JavaScript 1.4 Grammar

success

fail

Jul	AUG	Jun
	15
1999	2000	2002

8 captures

15 Aug 2000 - 17 Aug 2003

About this capture

This is a LR(1) grammar written by waldemar that describes the state of ECMAScript as of February 1999. The grammar is complete except for semicolon insertion (the OptionalSemicolon grammar state can sometimes reduce to «empty») and distinguishing RegularExpression from / and /=. Also, there is some controversy about elision in array literals, so this feature has been omitted for now.

Grammar syntax

Grammar productions may expand nonterminals into empty right sides. Such right sides are indicated as «empty».

A number of rules in the grammar occur in groups of analogous rules. Rather than list them individually, these groups have been summarized using the shorthand illustrated by the example below:

introduce grammar arguments a and b. If these arguments later parametrize the nonterminal on the left side of a rule, that rule is implicitly replicated into a set of rules in each of which a grammar argument is consistently substituted by one of its variants. For example,

AssignmentExpression^a,b

ConditionalExpression^a,b

| LeftSideExpression^a = AssignmentExpression^normal,b

| LeftSideExpression^a CompoundAssignment AssignmentExpression^normal,b

AssignmentExpression^{normal,allowIn}

ConditionalExpression^{normal,allowIn}

| LeftSideExpression^normal = AssignmentExpression^{normal,allowIn}

| LeftSideExpression^normal CompoundAssignment AssignmentExpression^{normal,allowIn}

AssignmentExpression^normal,noIn

ConditionalExpression^normal,noIn

| LeftSideExpression^normal = AssignmentExpression^normal,noIn

| LeftSideExpression^normal CompoundAssignment AssignmentExpression^normal,noIn

AssignmentExpression^{initial,allowIn}

ConditionalExpression^{initial,allowIn}

| LeftSideExpression^initial = AssignmentExpression^{normal,allowIn}

| LeftSideExpression^initial CompoundAssignment AssignmentExpression^{normal,allowIn}

AssignmentExpression^initial,noIn

ConditionalExpression^initial,noIn

| LeftSideExpression^initial = AssignmentExpression^normal,noIn

| LeftSideExpression^initial CompoundAssignment AssignmentExpression^normal,noIn

AssignmentExpression^{normal,allowIn} is now an unparametrized nonterminal and processed normally by the grammar.

Some of the expanded rules (such as the fourth one in the example above) may be unreachable from the starting nonterminal Program; these are ignored.

Expressions

Primary Expressions

PrimaryExpression^normal

SimpleExpression

| FunctionExpression

| ObjectLiteral

PrimaryExpression^initial SimpleExpression

SimpleExpression

this

| null

| true

| false

| Number

| String

| Identifier

| RegularExpression

| ParenthesizedExpression

| ArrayLiteral

ParenthesizedExpression ( Expression^{normal,allowIn} )

Function Expressions

FunctionExpression

AnonymousFunction

| NamedFunction

Object Literals

ObjectLiteral

{ }

| { FieldList }

FieldList

LiteralField

| FieldList , LiteralField

LiteralField Identifier : AssignmentExpression^{normal,allowIn}

Array Literals

ArrayLiteral

[ ]

| [ ElementList ]

ElementList

LiteralElement

| ElementList , LiteralElement

LiteralElement AssignmentExpression^{normal,allowIn}

Left-Side Expressions

LeftSideExpression^a

CallExpression^a

| ShortNewExpression

CallExpression^a

PrimaryExpression^a

| FullNewExpression

| CallExpression^a MemberOperator

| CallExpression^a Arguments

FullNewExpression new FullNewSubexpression Arguments

ShortNewExpression new ShortNewSubexpression

FullNewSubexpression

PrimaryExpression^normal

| FullNewExpression

| FullNewSubexpression MemberOperator

ShortNewSubexpression

FullNewSubexpression

| ShortNewExpression

MemberOperator

[ Expression^{normal,allowIn} ]

| . Identifier

Arguments

( )

| ( ArgumentList )

ArgumentList

AssignmentExpression^{normal,allowIn}

| ArgumentList , AssignmentExpression^{normal,allowIn}

Postfix Operators

PostfixExpression^a

LeftSideExpression^a

| LeftSideExpression^a ++

| LeftSideExpression^a --

Unary Operators

UnaryExpression^a

PostfixExpression^a

| delete LeftSideExpression^normal

| void UnaryExpression^normal

| typeof UnaryExpression^normal

| ++ LeftSideExpression^normal

| -- LeftSideExpression^normal

| + UnaryExpression^normal

| - UnaryExpression^normal

| ~ UnaryExpression^normal

| ! UnaryExpression^normal

Multiplicative Operators

MultiplicativeExpression^a

UnaryExpression^a

| MultiplicativeExpression^a * UnaryExpression^normal

| MultiplicativeExpression^a / UnaryExpression^normal

| MultiplicativeExpression^a % UnaryExpression^normal

Additive Operators

AdditiveExpression^a

MultiplicativeExpression^a

| AdditiveExpression^a + MultiplicativeExpression^normal

| AdditiveExpression^a - MultiplicativeExpression^normal

Bitwise Shift Operators

ShiftExpression^a

AdditiveExpression^a

| ShiftExpression^a << AdditiveExpression^normal

| ShiftExpression^a >> AdditiveExpression^normal

| ShiftExpression^a >>> AdditiveExpression^normal

Relational Operators

RelationalExpression^a,allowIn

ShiftExpression^a

| RelationalExpression^a,allowIn < ShiftExpression^normal

| RelationalExpression^a,allowIn > ShiftExpression^normal

| RelationalExpression^a,allowIn <= ShiftExpression^normal

| RelationalExpression^a,allowIn >= ShiftExpression^normal

| RelationalExpression^a,allowIn instanceof ShiftExpression^normal

| RelationalExpression^a,allowIn in ShiftExpression^normal

RelationalExpression^a,noIn

ShiftExpression^a

| RelationalExpression^a,noIn < ShiftExpression^normal

| RelationalExpression^a,noIn > ShiftExpression^normal

| RelationalExpression^a,noIn <= ShiftExpression^normal

| RelationalExpression^a,noIn >= ShiftExpression^normal

| RelationalExpression^a,noIn instanceof ShiftExpression^normal

Equality Operators

EqualityExpression^a,b

RelationalExpression^a,b

| EqualityExpression^a,b == RelationalExpression^normal,b

| EqualityExpression^a,b != RelationalExpression^normal,b

| EqualityExpression^a,b === RelationalExpression^normal,b

| EqualityExpression^a,b !== RelationalExpression^normal,b

Binary Bitwise Operators

BitwiseAndExpression^a,b

EqualityExpression^a,b

| BitwiseAndExpression^a,b & EqualityExpression^normal,b

BitwiseXorExpression^a,b

BitwiseAndExpression^a,b

| BitwiseXorExpression^a,b ^ BitwiseAndExpression^normal,b

BitwiseOrExpression^a,b

BitwiseXorExpression^a,b

| BitwiseOrExpression^a,b | BitwiseXorExpression^normal,b

Binary Logical Operators

LogicalAndExpression^a,b

BitwiseOrExpression^a,b

| LogicalAndExpression^a,b && BitwiseOrExpression^normal,b

LogicalOrExpression^a,b

LogicalAndExpression^a,b

| LogicalOrExpression^a,b || LogicalAndExpression^normal,b

Conditional Operator

ConditionalExpression^a,b

LogicalOrExpression^a,b

| LogicalOrExpression^a,b ? AssignmentExpression^normal,b : AssignmentExpression^normal,b

Assignment Operators

AssignmentExpression^a,b

ConditionalExpression^a,b

| LeftSideExpression^a = AssignmentExpression^normal,b

| LeftSideExpression^a CompoundAssignment AssignmentExpression^normal,b

CompoundAssignment

*=

| /=

| %=

| +=

| -=

| <<=

| >>=

| >>>=

| &=

| ^=

| |=

Expressions

Expression^a,b

AssignmentExpression^a,b

| Expression^a,b , AssignmentExpression^normal,b

OptionalExpression

Expression^{normal,allowIn}

| «empty»

Statements

Statement^w

EmptyStatement

| ExpressionStatement OptionalSemicolon

| VariableDefinition OptionalSemicolon

| Block

| LabeledStatement^w

| IfStatement^w

| SwitchStatement

| DoStatement OptionalSemicolon

| WhileStatement^w

| ForStatement^w

| WithStatement^w

| ContinueStatement OptionalSemicolon

| BreakStatement OptionalSemicolon

| ReturnStatement OptionalSemicolon

| ThrowStatement OptionalSemicolon

| TryStatement

OptionalSemicolon ;

Empty Statement

EmptyStatement ;

Expression Statement

ExpressionStatement Expression^{initial,allowIn}

Variable Definition

VariableDefinition var VariableDeclarationList^allowIn

VariableDeclarationList^b

VariableDeclaration^b

| VariableDeclarationList^b , VariableDeclaration^b

VariableDeclaration^b Identifier VariableInitializer^b

VariableInitializer^b

«empty»

| = AssignmentExpression^normal,b

Block

Block { BlockStatements }

BlockStatements

«empty»

| BlockStatementsPrefix

BlockStatementsPrefix

Statement^full

| BlockStatementsPrefix Statement^full

Labeled Statements

LabeledStatement^w Identifier : Statement^w

If Statement

IfStatement^full

if ParenthesizedExpression Statement^full

| if ParenthesizedExpression Statement^noShortIf else Statement^full

IfStatement^noShortIf if ParenthesizedExpression Statement^noShortIf else Statement^noShortIf

Switch Statement

SwitchStatement

switch ParenthesizedExpression { }

| switch ParenthesizedExpression { CaseGroups LastCaseGroup }

CaseGroups

«empty»

| CaseGroups CaseGroup

CaseGroup CaseGuards BlockStatementsPrefix

LastCaseGroup CaseGuards BlockStatements

CaseGuards

CaseGuard

| CaseGuards CaseGuard

CaseGuard

case Expression^{normal,allowIn} :

| default :

Do-While Statement

DoStatement do Statement^full while ParenthesizedExpression

While Statement

WhileStatement^w while ParenthesizedExpression Statement^w

For Statements

ForStatement^w

for ( ForInitializer ; OptionalExpression ; OptionalExpression ) Statement^w

| for ( ForInBinding in Expression^{normal,allowIn} ) Statement^w

ForInitializer

«empty»

| Expression^normal,noIn

| var VariableDeclarationList^noIn

ForInBinding

LeftSideExpression^normal

| var VariableDeclaration^noIn

With Statement

WithStatement^w with ParenthesizedExpression Statement^w

Continue and Break Statements

ContinueStatement continue OptionalLabel

BreakStatement break OptionalLabel

OptionalLabel

«empty»

| Identifier

Return Statement

ReturnStatement return OptionalExpression

Throw Statement

ThrowStatement throw Expression^{normal,allowIn}

Try Statement

TryStatement

try Block CatchClauses

| try Block FinallyClause

| try Block CatchClauses FinallyClause

CatchClauses

CatchClause

| CatchClauses CatchClause

CatchClause catch ( Identifier ) Block

FinallyClause finally Block

Function Definition

FunctionDefinition NamedFunction

AnonymousFunction function FormalParametersAndBody

NamedFunction function Identifier FormalParametersAndBody

FormalParametersAndBody ( FormalParameters ) { TopStatements }

Grammar syntax

Expressions

Primary Expressions

Function Expressions

Object Literals

Array Literals

Left-Side Expressions

Postfix Operators

Unary Operators

Multiplicative Operators

Additive Operators

Bitwise Shift Operators

Relational Operators

Equality Operators

Binary Bitwise Operators

Binary Logical Operators

Conditional Operator

Assignment Operators

Expressions

Statements

Empty Statement

Expression Statement

Variable Definition

Block

Labeled Statements

If Statement

Switch Statement

Do-While Statement

While Statement

For Statements

With Statement

Continue and Break Statements

Return Statement

Throw Statement

Try Statement

Function Definition

Programs